WHILE, REPEAT, EXIT, CONTINUE and RETURN

WHILE: test, then run

WHILE Rest >= Dose DO
  Rest := Rest - Dose;
  Shots := Shots + 1;
END_WHILE

The condition is tested before every pass, so a condition that is false at the start means the body never runs. Use it when the iteration count is not known in advance.

REPEAT: run, then test

REPEAT
  Guess := (Guess + Value / Guess) / 2.0;
  Count := Count + 1;
UNTIL ABS(Guess * Guess - Value) < 0.01 OR Count >= 20
END_REPEAT

The body runs at least once, then the condition is tested. Note the inverted sense: REPEAT runs until the condition becomes true, WHILE runs while it stays true.

Jump statements

FOR i := 1 TO 200 DO
  IF Ids[i] = Wanted THEN
    Found := i;
    EXIT;                 (* found it, no point checking the rest *)
  END_IF
END_FOR

RETURN is most useful as a gate at the top of a program: if the conditions are not right, do nothing.

IF NOT Enabled OR Faulted THEN
  Pump := FALSE;
  RETURN;
END_IF
(* everything below runs only while the enable holds *)

CONTINUE is not available on every vendor, and an IF wrapping the body usually says the same thing more clearly.

Why WHILE is dangerous

A FOR loop has known bounds on entry, so the worst it can be is slow. A WHILE loop is bounded by a condition, and if the condition never goes false the loop never ends, the scan never ends, and the watchdog stops the controller. The classic disaster:

WHILE Level < 50.0 DO       (* disaster *)
  Pump := TRUE;
END_WHILE

Level is a field input, taken from the input image, which does not refresh mid-scan. It will never change inside the loop, and Pump has not reached the output yet either. The controller will fault. Never wait on a field input inside a loop. Waiting in a PLC is written as a state machine, not as a loop.

How to bound a WHILE

Put a guard counter into the condition itself. Two lines turn a dangerous loop into one that is guaranteed to end:

Guard := 0;
WHILE Rest >= Dose AND Guard < 50 DO
  Rest  := Rest - Dose;
  Guard := Guard + 1;
END_WHILE

Whatever the data does, the loop ends after 50 passes at most. And if you want to know whether it ended on the guard rather than on the real condition, test Guard >= 50 afterwards and raise a diagnostic flag.

What runs in the lab

This lesson's program uses WHILE only, with a guard. The REPEAT, EXIT and RETURN blocks above are there to read and to take into your vendor's environment.

Which loop do I pick?