WHILE و REPEAT و EXIT و CONTINUE و RETURN

WHILE: افحص ثم نفّذ

WHILE Rest >= Dose DO
  Rest := Rest - Dose;
  Shots := Shots + 1;
END_WHILE

الشرط يُفحص قبل كل تكرار. فإن كان كاذباً من أول مرة لم يُنفّذ الجسم أبداً. استخدمها عندما يكون عدد التكرارات غير معروف مسبقاً.

REPEAT: نفّذ ثم افحص

REPEAT
  Guess := (Guess + Value / Guess) / 2.0;
  Count := Count + 1;
UNTIL ABS(Guess * Guess - Value) < 0.01 OR Count >= 20
END_REPEAT

الجسم ينفّذ مرة واحدة على الأقل ثم يُفحص الشرط. والمنطق معكوس: REPEAT تستمر حتى يصبح الشرط صحيحاً، و WHILE تستمر طالما الشرط صحيح.

تعليمات القفز

FOR i := 1 TO 200 DO
  IF Ids[i] = Wanted THEN
    Found := i;
    EXIT;                 (* وجدناه، لا معنى لفحص الباقي *)
  END_IF
END_FOR

RETURN مفيدة كـ بوابة في أول البرنامج: إذا لم تكن الظروف صالحة، لا تنفّذ شيئاً.

IF NOT Enabled OR Faulted THEN
  Pump := FALSE;
  RETURN;
END_IF
(* كل ما تحت هذا السطر ينفّذ فقط إذا كان التمكين قائماً *)

CONTINUE ليست موجودة عند كل المصنّعين، وغالباً يمكن استبدالها بـ IF يغطي الجسم، وهذا أوضح.

لماذا WHILE خطرة

FOR حدودها معروفة عند الدخول، فأسوأ حالاتها بطء. أما WHILE فحدودها شرط، وإذا لم يصبح الشرط كاذباً فالحلقة لا تنتهي، والمسح لا ينتهي، فيتدخل المؤقت الحارس ويوقف المتحكم. مثال كارثي:

WHILE Level < 50.0 DO       (* كارثة *)
  Pump := TRUE;
END_WHILE

Level مدخل حقلي، ومأخوذ من صورة المداخل التي لا تتحدّث داخل الدورة. لن يتغير داخل الحلقة أبداً، والمضخة لم تُكتب إلى المخرج بعد. المتحكم سيتوقف. لا تنتظر مدخلاً حقلياً داخل حلقة. الانتظار في PLC يُكتب بآلة حالات، لا بحلقة.

كيف تُقيّد WHILE

ضع عدّاداً حارساً في الشرط نفسه. سطران يحوّلان حلقة خطرة إلى حلقة مؤكدة الانتهاء:

Guard := 0;
WHILE Rest >= Dose AND Guard < 50 DO
  Rest  := Rest - Dose;
  Guard := Guard + 1;
END_WHILE

مهما حدث للبيانات، الحلقة تنتهي بعد 50 تكراراً كأقصى حد. وإن أردت أن تعلم أنها انتهت بالحارس لا بالشرط الحقيقي، افحص Guard >= 50 بعدها وارفع علماً تشخيصياً.

ما يعمل في المختبر

برنامج هذا الدرس يستخدم WHILE فقط، مع حارس. كتل REPEAT و EXIT و RETURN أعلاه معروضة للقراءة ولبيئة المصنّع.

أي حلقة أختار؟