اكتب كتلتك الوظيفية: FUNCTION_BLOCK لمحرك

FUNCTION_BLOCK FB_Motor
VAR_INPUT
  Start    : BOOL;   (* نبضة تشغيل *)
  Stop     : BOOL;   (* نبضة إيقاف، تغلب دائماً *)
  Feedback : BOOL;   (* تماس مساعد من الكونتاكتور *)
  Ack      : BOOL;   (* إقرار الخطأ *)
  FbTime   : TIME;   (* زمن انتظار إشارة الرجوع *)
END_VAR
VAR_OUTPUT
  Run   : BOOL;      (* إلى الكونتاكتور *)
  Alarm : BOOL;      (* خطأ ممسوك *)
END_VAR
VAR
  FbTimer : TON;     (* ذاكرة خاصة بكل نسخة *)
END_VAR

(* إمساك ذاتي، والخطأ والإيقاف يغلبان *)
Run := (Start OR Run) AND NOT Stop AND NOT Alarm;

(* أمرنا بالتشغيل ولم تعد إشارة الرجوع خلال الزمن المسموح *)
FbTimer(IN := Run AND NOT Feedback, PT := FbTime);

IF FbTimer.Q THEN
  Alarm := TRUE;     (* ممسوك: يبقى بعد زوال السبب *)
END_IF;

IF Ack THEN
  Alarm := FALSE;
END_IF;

END_FUNCTION_BLOCK

VAR
  M101 : FB_Motor;
  M102 : FB_Motor;
  M103 : FB_Motor;
END_VAR

M101(Start := Btn1, Stop := StopAll, Feedback := Aux1, Ack := AckBtn, FbTime := T#2s);
M102(Start := Btn2, Stop := StopAll, Feedback := Aux2, Ack := AckBtn, FbTime := T#2s);
M103(Start := Btn3, Stop := StopAll, Feedback := Aux3, Ack := AckBtn, FbTime := T#5s);

K101 := M101.Run;
K102 := M102.Run;
AnyFault := M101.Alarm OR M102.Alarm OR M103.Alarm;

M101(Start := Btn1, ...);
K101 := M101.Run;      (* صحيح: القيمة من هذا المسح *)

FUNCTION_BLOCK FB_RunHours
VAR_INPUT
  Running : BOOL;
END_VAR
VAR_IN_OUT
  Hours : REAL;      (* عدّاد ساعات يملكه البرنامج ويحدّثه الكتلة *)
END_VAR